Como organizar aquelas pastas malucas cheias de arquivos com apenas um clique.

Sabe quando você vai formando uma criação de arquivos no desktop, ou na pasta C:\TEMP e depois do, digamos, milésimo arquivo, tudo está muito confuso, mas ao mesmo tempo tem arquivo demais pra você perder todos esses 30 minutos organizando? Mas espere! Seus problemas acabaram!

Na verdade nem é uma solução assim mirabolante, mas funciona que é uma beleza.

A ideia é criar um arquivo em lote – um batch file – que é uma sequencia de instruções ao prompt de comando  do Windows.

Se você não entendeu isso, significa que vamos programar o windows para fazer várias tarefas automaticamente toda vez que dispararmos esse arquivo.

A sequencia de passos é bem simples. Vamos lá.

  1. Abra o Notepad
  2. Copie os comandos a seguir (ou baixe esse organizar.txt aqui e depois mude o nome para organizar.cmd)
    @Echo off
    CLS
    Echo.
    Echo Voce tambem quer organizar os arquivos de atalho (*.lnk)?
    SET /P resposta=Digite SIM (tudo em maiusculo) para confirmar.
    Echo.
    Echo ! ShortCuts Files
    if "%resposta%"=="SIM" (
     if not exist _ShortCuts\nul mkdir _ShortCuts
     move *.lnk _ShortCuts > nul)
    Echo.
    Echo ! Images
    Echo !--- JPG
    for %%i in (jpg jp2 jp2 jpeg) do if exist *.%%i (
     if not exist _Images\JPEG\nul mkdir _Images\JPEG
     move *.%%i _Images\JPEG > nul)
    
    Echo !--- GIF
    if exist *.gif (
     if not exist _Images\GIF\nul mkdir _Images\GIF
     move *.gif _Images\GIF > nul)
    
    Echo !--- PNG
    if exist *.png (
     if not exist _Images\PNG\nul mkdir _Images\PNG
     move *.png _Images\PNG > nul)
    
    Echo !--- PSD
    if exist *.psd (
     if not exist _Images\PSD\nul mkdir _Images\PSD
     move *.psd _Images\PSD > nul)
    
    Echo !__ Other image formats
    for %%i in (tif tiff bmp) do IF EXIST *.%%i (
     if not exist _Images\nul mkdir _Images
     move *.%%i _Images > nul)
    Echo.
    Echo ! Movies and animations
    for %%i in (mov mpg mp4 avi vob wmv m4v f4v flv) do IF EXIST *.%%i (
     if not exist _Movies\nul mkdir _Movies
     move *.%%i _Movies > nul)
    Echo.
    Echo ! Audio files
    for %%i in (aac opus mp3 ogg wav pcm au aiff pcm) do IF EXIST *.%%i (
     if not exist _Audio\nul mkdir _Audio
     move *.%%i _Audio > nul)
    
    Echo.
    Echo ! Portable documents and e-Books
    for %%i in (bib bibtex xps oxps pdf pub cba cbm cbt cb7 chm djvu epub pdb azw azw3 kf8 kfx lit) do IF EXIST *.%%i (
     if not exist _PDF\nul mkdir _PDF
     move *.%%i _PDF > nul)
    
    Echo.
    Echo ! Archived ZIP RAR ISO and other acrchive formats 
    for %%i in (zip rar iso 7z tar cab dmg) do IF EXIST *.%%i (
     if not exist _ZIP_RAR_ISO_ETC\nul mkdir _ZIP_RAR_ISO_ETC
     move *.%%i _ZIP_RAR_ISO_ETC > nul)
    
    Echo.
    Echo ! Office files and general txt
    for %%i in (gdoc gsheet gslides csv txt rtf doc dot xls xlt xlm docm docx docb dotx dotm ppt xla xlam xli xlw pptx pptm ppam ppsx ppsm sldx sldm odt ods) do IF EXIST *.%%i (
     if not exist _DOC\nul mkdir _DOC
     move *.%%i _DOC > nul)
    
    Echo.
    Echo ! Torrent files
    for %%i in (torrent) do IF EXIST *.%%i (
     if not exist _Torrents\nul mkdir _Torrents
     move *.%%i _Torrents > nul)
    
    Echo.
    Echo ! Executables files
    for %%i in (exe com msi msp) do IF EXIST *.%%i (
     if not exist _Executables\Windows\nul mkdir _Executables\Windows
     move *.%%i _Executables\Windows > nul)
    
    Echo !-- Android APK
    for %%i in (apk) do IF EXIST *.%%i (
     if not exist _Executables\Android\nul mkdir _Executables\Android
     move *.%%i _Executables\Android > nul)
    
    Echo !__AutoHotKey files
    for %%i in (ahk) do IF EXIST *.%%i (
     if not exist _Executables\AutoHotKey\nul mkdir _Executables\AutoHotKey
     move *.%%i _Executables\AutoHotKey > nul)
    Echo.
    Echo ! Web related files
    for %%i in (xml html htm php css js url) do IF EXIST *.%%i (
     if not exist _WebFiles\nul mkdir _WebFiles
     move *.%%i _WebFiles > nul)
    Echo.
    Echo ! LOG files
    for %%i in (log) do IF EXIST *.%%i (
     if not exist _LogFiles\nul mkdir _LogFiles
     move *.%%i _LogFiles > nul)
    Echo.
    Echo ! Graphic files
    Echo !--- Illustrator Files
    if exist *.ai (
     if not exist _Graphic\Illustrator\nul mkdir _Graphic\Illustrator
     move *.ai _Graphic\Illustrator > nul)
    Echo !--- Corel Files
    for %%i in (cdr cdt) do IF EXIST *.%%i (
     if not exist _Graphic\Corel\nul mkdir _Graphic\Corel
     move *.%%i _Graphic\Corel > nul)
    Echo !--- Font Files
    for %%i in (ttf otf) do IF EXIST *.%%i (
     if not exist _Graphic\Fonts\nul mkdir _Graphic\Fonts
     move *.%%i _Graphic\Fonts > nul)
    Echo !--- 3D Files
    for %%i in (sldprt max 3ds dxf) do IF EXIST *.%%i (
     if not exist _Graphic\3D\nul mkdir _Graphic\3D
     move *.%%i _Graphic\3D > nul)
    Echo !__ Other graphic file formats
    for %%i in (eps wmf svg swf abr afdesign) do IF EXIST *.%%i (
     if not exist _Graphic\Other\nul mkdir _Graphic\Other
     move *.%%i _Graphic\Other > nul)
    Echo.
    Echo End of process.
    Echo.
    PAUSE
  3. Salve o arquivo no Desktop (ou na pasta que precisa ser organizada) com o nome organizar.cmd
    (você precisa salvar com essa extensão, caso contrário o Windows não reconhece como um arquivo de lote)
  4. De um clique duplo no arquivo para executar os comando e organizar a bagunça.

Esse batch cria algumas pastas novas e move os arquivos para dentro delas, de acordo com o tipo.

Arquivos JPG, GIF, BMP (e outras imagens) vão para dentro da pasta _Imagens

Arquivos do tipo DOC, XLS, DOCX, TXT (e outros documentos de pacotes office), vão para dentro da pasta _DOC

Arquivos de áudio, vídeo, torrents, cada um para suas pastas respectivas.

O tipo de classificação que fiz foi o que mas fez sentido pra mim, alguns arquivos vão parar em pastas próprias dentro dessas pastas novas, outros arquivos (os de audio, por exemplo) vão tudo pro mesmo lugar. Você pode fuçar no código e fazer sua própria classificação.

Ah sim, no início do Batch ele pergunta se você gostaria de mover os arquivos LNK que são arquivos de atalho para outras pastas ou para programas. Só responda SIM se você realmente sabe o que está fazendo, se não, pode ser que perca o acesso a alguns programas e ganhe fios de cabelo branco no processo.


 

News Reporter